plugins {
    id 'fabric-loom' version '1.16-SNAPSHOT'
}

base.archivesName = "${project.mod_id}-fabric-1216"

// 1.21.6 은 Java 21 런타임. release 21 로 컴파일.
java {
    toolchain.languageVersion = JavaLanguageVersion.of(25)
}
tasks.withType(JavaCompile).configureEach {
    options.release = 21
}

// common/ 디렉토리의 로더 비종속 소스 포함. Mojang 매핑으로 컴파일됨.
sourceSets {
    main {
        java {
            srcDirs += "${rootDir}/common/src/main/java"
        }
    }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.mc_1216}"
    mappings loom.officialMojangMappings()
    modImplementation "net.fabricmc:fabric-loader:${project.fabric_loader_1216}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_1216}"
}

loom {
    serverOnlyMinecraftJar()
}

processResources {
    inputs.property "version", project.version
    inputs.property "mod_id", project.mod_id

    filteringCharset = 'UTF-8'

    filesMatching("fabric.mod.json") {
        expand(
            "version": project.version,
            "mod_id": project.mod_id
        )
    }
}

jar {
    from(rootProject.file("LICENSE")) {
        rename { "${it}_${project.mod_id}_fabric_1216" }
    }
}