plugins {
    id 'net.neoforged.moddev' version '2.0.97'
}

base.archivesName = "${project.mod_id}-neoforge-1216"

// NeoForge 1.21.6 은 Java 21. release 21 로 컴파일.
java {
    toolchain.languageVersion = JavaLanguageVersion.of(25)
}
tasks.withType(JavaCompile).configureEach {
    options.release = 21
}

sourceSets {
    main {
        java {
            srcDirs += "${rootDir}/common/src/main/java"
        }
    }
}

neoForge {
    version = project.neoforge_1216
}

processResources {
    inputs.property "version", project.version
    inputs.property "mod_id", project.mod_id
    inputs.property "minecraft_version", project.mc_1216
    inputs.property "neoforge_version", project.neoforge_1216

    filteringCharset = 'UTF-8'

    filesMatching("META-INF/neoforge.mods.toml") {
        expand(
            "version": project.version,
            "mod_id": project.mod_id,
            "minecraft_version": project.mc_1216,
            "neoforge_version": project.neoforge_1216
        )
    }
}

jar {
    from(rootProject.file("LICENSE")) {
        rename { "${it}_${project.mod_id}_neoforge_1216" }
    }
}